*label marriagetalk
*page_break

"You didn't give me an answer, back at the @{(aresmarriagetalk) palace. Not really." You pause to look at him. "Is|palace, before you asked me to sneak away. Is} marriage something you want?"

@{(aresmarriagetalk) He shrugs|You might as well address it, while you're on the subject. Sort of}.

@{(aresmarriagetalk) But some of the tension returns to his shoulders|He shrugs, but his fingers curl into a fist next to yours|}.

"I think the real question is, does what I want matter more than what's best for the realms?"

His eyes are serious when they meet yours. They match the grove, a mosaic of greens, browns and gold.

@{(marriage) "You don't want what's best for the realms?" you wonder|"Can the two not align?" you retort|"The two shouldn't be conflated," you assert|"And who determines what's best for the realms? Our parents are not the Fates," you challenge}.

Despite the sorrow creeping into his gaze, his lips quirk up. @{(marriage) "I do."|"I suppose they could."|"And yet."|"And yet."} 
*return

*label predrakon

*choice
    #I @{(wentwithares) follow|approach} as quietly as possible.
        You tiptoe @{(wentwithares) after|towards} him, timing your steps so they're masked by the stream's burbling.
        
        *if stealth > 50
            *set Ares %+5
            *set pantheonplayer %+5
            *set daemonhandling %+5
            It's easy. You move like a shadow, soundless and sly.

            The closer you get, the more excited Ares looks.
            *goto drakoneggs
        *else
            *set olympusinfluence %-5
            And promptly trip on a wet stone, causing a ruckus loud enough to reach the palace.

            By the time you get up, you can barely meet his eye.

            "Are you alright?" he murmurs. 

            You nod, but you doubt your pride will ever recover.
            *goto drakoneggs
    #I @{(wentwithares) follow|approach} cautiously, checking for threats.
        You doubt this is an ambush, but it doesn't hurt to be prepared.

        *if charm < 50
            *set pantheonplayer %+5
            *set daemonhandling %+5
            Ares himself seems to grow more alert, squaring his broad shoulders and scanning the oak grove alongside you.

            It's quiet save for the stream and the distant buzz of bees. Still, you move slowly, keeping your eyes and ears peeled until you reach his side.
            *goto drakoneggs 
        *else
            *set Ares %-5
            *set pantheonplayer %-10
            Ares is far from impressed. He rolls his eyes and waves you closer with a lot more urgency.

            Sighing, you pick up the pace.
            *goto drakoneggs
    #"I WILL TALK IF I WISH," I yell. Nobody tells me what to do.
        He winces as though you just slapped him. You lift your chin, daring him to shush you again.
        
        *if dutiful < 55
            *set Ares %-5
            *set maverickgoddess %+10
            Whatever he sees in your face makes him relent. He lifts his hands in apology then urges you closer. 

            "Please," he murmurs.

            That's better.
            *goto drakoneggs
        *else
            *set Ares %-10
            *set pantheonplayer %-5
            He does. The audacity!

            Sighing, you @{(wentwithares) follow after|march towards} him. Whatever's got him all worked up better be worth it.
            *goto drakoneggs

*label drakoneggs
*page_break

@{(wentwithares) He kneels by the hollow. You do the same|You kneel beside him} and let out a gasp. 

There, tucked into the tree, a clutch of @{(wentwithares) drakon|quivering drakon} eggs. Three of them, each as big as Ares's hand, snuggled into what appears to be a nest made out of one of his tunics.

You've never seen a clutch this close. It's dangerous to be around them, even for deities. Drakon hens will do anything to protect their young. It's why you used to climb the trees and hide among their branches when you were children.

From this distance, you can easily make out every color dancing on the iridescent shells, and the faint outline of the embryo curled up inside.

"The mother?" you whisper, glacing back at Ares.

Grief shadows his face. 

"Artemis," he whispers back, nocking an invisible arrow into an invisible bow.

@{(ruthless < 50) How cruel|Cruel, yes. But also kind of impressive}.
*return

*label lake

You can feel the sharpness of his gaze against you, violet steel pressing into your naked @{(injured) body, snagging on your scar|body}. You hold it like you would a knife. @{(demure < 50) Expertly, enjoying the sense of power it brings you|Gingerly, so as not to cut yourself on the blade}.
        
"You were saying?"

The sound of your voice drags his focus back to your face. Your lips. You're close enough to make out the water droplets clinging to his long lashes, the moths etched into the beads adorning his hair.
        
He clears his throat, but his words still come out a rasp. "I believe I was commenting on your blatant ogling."
*return

*label declaration4
*page_break

Suddenly, you can't bear the distance between you. He must feel it too, for he's by your side and kissing you no sooner has the thought formed.

*if (chose = 1) and (aresoutcome = 3)
    *set laterkiss true
    Softly, at first. A slow kiss, meant to be savored.
    *goto areskiss
*elseif (chose = 2) and (theronoutcome = 3)
    *set laterkiss true
    *goto theronkiss
*elseif (chose = 3) and (morpheusoutcome = 3)
    *if justkissedmorpheus = false
        *set laterkiss2 true
        *goto morpheuskiss
    *else
        *return
*else
    *return

*label theronkiss

You're used to the charming Lord, who smiles and flatters and soothes, who shows restraint and grace, even in his nightmares. 

But there is nothing restrained about the way his lips claim yours. He drinks you in as though you're water and he's parched. His rugged hands trace the curve of your neck, his beard gently scratches your cheeks. 

And you melt into him, lost to the beat of his heart pounding against your chest and the taste of wine and salt on his tongue.
*return

*label morpheuskiss
And it's like everything else with Morpheus. Unyielding, a contest fought with wilful lips and searching hands instead of barbed words and flowers on a gate.

You don't know who is winning or losing. You don't know anything but the imprint of his arms around your waist, the rough silk of his hair beneath your fingers, the slow provocation delivered by his tongue.
*return

*label areskiss

He tastes like ambrosia, sweet and divine.

Then he's hauling you closer, and you're melting into the vastness of his chest, the warmth of his skin, the brush of his tongue.

Your hands slide from his cheeks and bury into his hair. His fingers graze your cheek, your @{(hair) hair|curls|braids|hair}, your neck.
*return 

*label hermeszeus

"You wanted worship, so I got you worship. Then you wanted more worship, so I got you more worship. Then you wanted [i]more[/i] worship…I'm sure you can sense the pattern. And I'm sure you can guess what keeping up with such increasing demands required. Yes, you guessed it, worship." He smiles bitterly. "So what if I acquired it by pushing nightmares to certain patronless cities? And if I unleashed Argus on Morpheus when he confronted me about it? I stand by what I did, and if @{(irisdecides) my busybody aide|Hades's busybody daughter} hadn't forced my hand, I would've kept on doing it, if only to ensure our victory over the Giants."

*label punishmentchoice
*page_break

In the wake of Hermes's confession, you expect thunder, perhaps a lightning bolt to crack @{(irisdecides) Theron's home in half|the glossy floor}, maybe even strike down Hermes himself. 

But there is neither. Instead, Zeus looks at his son with nothing but pure contempt.

"I should throw you into Tartarus for this," he says.

Hermes @{(irisdecides) balks, then, and the harpies have to tighten their grip on him|balks}. "Father, please, you can't possibly be–"

Zeus lifts his hand, shutting the herald up before turning his gaze to @{(irisdecides) Iris|you}.
*return